ايران ويج

سلام
معادل کد زیر در دلفی چطوری میشه؟ یعنی چطوری کد زیر به دلفی تبدیل کنم که درست کار کنه؟؟

کد: 
// Decrypt data from DATA_BLOB DataOut to DATA_BLOB DataVerify.

//--------------------------------------------------------------------

// Declare and initialize variables.

DATA_BLOB DataOut;

DATA_BLOB DataVerify;

LPWSTR pDescrOut =  NULL;

//--------------------------------------------------------------------

// The buffer DataOut would be created using the CryptProtectData

// function. If may have been read in from a file.

//--------------------------------------------------------------------

//   Begin unprotect phase.

if (CryptUnprotectData(

        &DataOut,

        &pDescrOut,

        NULL,                 // Optional entropy

        NULL,                 // Reserved

        NULL,                 // Here, the optional 

                              // prompt structure is not

                              // used.

        0,

        &DataVerify))

{

     printf("The decrypted data is: %s\n", DataVerify.pbData);

     printf("The description of the data was: %s\n",pDescrOut);

}

else

{

    printf("Decryption error!");

}

(۱۴-فروردین-۱۳۹۴, ۰۴:۲۶:۵۳)The.Ghost نوشته است: [ -> ]سلام
معادل کد زیر در دلفی چطوری میشه؟ یعنی چطوری کد زیر به دلفی تبدیل کنم که درست کار کنه؟؟

کد:
// Decrypt data from DATA_BLOB DataOut to DATA_BLOB DataVerify. //-------------------------------------------------------------------- // Declare and initialize variables. DATA_BLOB DataOut; DATA_BLOB DataVerify; LPWSTR pDescrOut = NULL; //-------------------------------------------------------------------- // The buffer DataOut would be created using the CryptProtectData // function. If may have been read in from a file. //-------------------------------------------------------------------- // Begin unprotect phase. if (CryptUnprotectData( &DataOut, &pDescrOut, NULL, // Optional entropy NULL, // Reserved NULL, // Here, the optional // prompt structure is not // used. 0, &DataVerify)) { printf("The decrypted data is: %s\n", DataVerify.pbData); printf("The description of the data was: %s\n",pDescrOut); } else { printf("Decryption error!"); }

من تونستم کد زیر بنویسم فقط الان نمیدونم اون رشته کد شده را باید چطوری به این تابع CryptUnprotectData بدم تا از حالت کد خارج کنه یا همان دیکد کنه؟؟؟

لطفا راهنمایی کنید؟؟؟؟؟؟؟

کد: 
unit Unit1;

interface

uses

  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,

  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

const

  CRYPTPROTECT_LOCAL_MACHINE = 4;

type

  TLargeByteArray = array [0 .. Pred(MaxInt)] of byte;

  PLargeByteArray = ^TLargeByteArray;

  _CRYPTOAPI_BLOB = record

    cbData: DWORD;

    pbData: PByte;

  end;

  DATA_BLOB = _CRYPTOAPI_BLOB;

  PDATA_BLOB = ^DATA_BLOB;

type

  _CRYPTPROTECT_PROMPTSTRUCT = record

    cbSize: DWORD;

    dwPromptFlags: DWORD;

    hwndApp: HWND;

    szPrompt: PWideChar;

  end;

  CRYPTPROTECT_PROMPTSTRUCT = _CRYPTPROTECT_PROMPTSTRUCT;

  PCRYPTPROTECT_PROMPTSTRUCT = ^CRYPTPROTECT_PROMPTSTRUCT;

function CryptProtectData(pDataIn: PDATA_BLOB;

  szDataDescr: PWideChar; pOptionalEntropy: PDATA_BLOB;

  pReserved: Pointer; pPromptStruct: PCRYPTPROTECT_PROMPTSTRUCT; dwFlags: DWORD;

  pDataOut: PDATA_BLOB): BOOL; stdcall; external 'Crypt32.dll';

function CryptUnprotectData(pDataIn: PDATA_BLOB; ppszDataDescr: PPWideChar;

  pOptionalEntropy: PDATA_BLOB; pReserved: Pointer;

  pPromptStruct: PCRYPTPROTECT_PROMPTSTRUCT; dwFlags: DWORD;

  pDataOut: PDATA_BLOB): BOOL; stdcall; external 'Crypt32.dll';

type

  TForm1 = class(TForm)

  private

    { Private declarations }

  public

    { Public declarations }

  end;

var

  Form1: TForm1;

implementation

procedure See;

var

  DataOut : DATA_BLOB;

  DataVerify : DATA_BLOB;

  pDescrOut : LPWSTR;

begin

 pDescrOut:=nil;

if (CryptUnprotectData(

        @DataOut,

        @pDescrOut,

        nil,                 // Optional entropy

        nil,                 // Reserved

        nil,                 // Here, the optional

                              // prompt structure is not

                              // used.

        0,

        @DataVerify)) then

  begin

   ShowMessage('1. '+Format('%S',[DataVerify.pbData]));

   ShowMessage('2. '+Format('%S',[pDescrOut]));

  end

 else

   ShowMessage('Decryption error!');

end;

{$R *.dfm}

end.

خروجی شما DataOut هست یعنی پارامتر اول

کد: 
CryptUnprotectData(@DataOut, nil, nil, nil, nil, 0,@DataCheck)

اینم یه کد نمونه:

کد: 
program SO17823083;

{$APPTYPE CONSOLE}

uses

  System.SysUtils, Winapi.Windows;

const

  CRYPTPROTECT_LOCAL_MACHINE = 4;

type

  TLargeByteArray = array [0 .. Pred(MaxInt)] of byte;

  PLargeByteArray = ^TLargeByteArray;

  _CRYPTOAPI_BLOB = record

    cbData: DWORD;

    pbData: PByte;

  end;

  DATA_BLOB = _CRYPTOAPI_BLOB;

  PDATA_BLOB = ^DATA_BLOB;

type

  _CRYPTPROTECT_PROMPTSTRUCT = record

    cbSize: DWORD;

    dwPromptFlags: DWORD;

    hwndApp: HWND;

    szPrompt: PWideChar;

  end;

  CRYPTPROTECT_PROMPTSTRUCT = _CRYPTPROTECT_PROMPTSTRUCT;

  PCRYPTPROTECT_PROMPTSTRUCT = ^CRYPTPROTECT_PROMPTSTRUCT;

function CryptProtectData(pDataIn: PDATA_BLOB;

  szDataDescr: PWideChar; pOptionalEntropy: PDATA_BLOB;

  pReserved: Pointer; pPromptStruct: PCRYPTPROTECT_PROMPTSTRUCT; dwFlags: DWORD;

  pDataOut: PDATA_BLOB): BOOL; stdcall; external 'Crypt32.dll';

function CryptUnprotectData(pDataIn: PDATA_BLOB; ppszDataDescr: PPWideChar;

  pOptionalEntropy: PDATA_BLOB; pReserved: Pointer;

  pPromptStruct: PCRYPTPROTECT_PROMPTSTRUCT; dwFlags: DWORD;

  pDataOut: PDATA_BLOB): BOOL; stdcall; external 'Crypt32.dll';

procedure FreeDataBlob(var Data: DATA_BLOB);

begin

  if Assigned(Data.pbData) then

    LocalFree(HLOCAL(Data.pbData));

  FillChar(Data, SizeOf(DATA_BLOB), 0);

end;

function GetDataBlobText(Data: DATA_BLOB): string;

begin

  SetString(Result, PChar(Data.pbData), Data.cbData div SizeOf(Char))

end;

function SetDataBlobText(const Text: string; var Data: DATA_BLOB): boolean;

begin

  FillChar(Data, SizeOf(DATA_BLOB), 0);

  if Length(Text) > 0 then

  begin

    Data.cbData := SizeOf(Char)*Length(Text);

    Data.pbData := Pointer(LocalAlloc(LPTR, Data.cbData));

    if Assigned(Data.pbData) then

    begin

      Move(Pointer(Text)^, Data.pbData^, Data.cbData);

      Result := True;

    end

    else

      Result := False;

  end

  else

    Result := True;

end;

function DecryptPassword(Password: string): string;

var

  DataIn: DATA_BLOB;

  dwFlags: DWORD;

  DataOut: DATA_BLOB;

  I, J: Integer;

  P: PByte;

begin

  Result := '';

  if (Length(Password) > 0) then

  begin

    DataIn.cbData := StrToIntDef('$' + Copy(Password, 1, 8), 0);

    if (DataIn.cbData > 0) then

    begin

      GetMem(DataIn.pbData, DataIn.cbData);

      I := DataIn.cbData;

      J := 9;

      P := DataIn.pbData;

      while (I > 0) and (J < Length(Password)) do

      begin

        Dec(I);

        P^ := StrToInt('$' + Copy(Password, J, 2));

        Inc(P);

        Inc(J, 2);

      end;

      dwFlags := CRYPTPROTECT_LOCAL_MACHINE;

      if CryptUnprotectData(@DataIn, nil, nil, nil, nil, dwFlags, @DataOut)

      then

      begin

        Result := GetDataBlobText(DataOut);

        LocalFree(Cardinal(DataOut.pbData));

      end;

      FreeMem(DataIn.pbData);

    end;

  end;

end;

procedure Test1;

var

  DataIn: DATA_BLOB;

  DataOut: DATA_BLOB;

  DataCheck: DATA_BLOB;

begin

  if SetDataBlobText('Hello world this is a test!', DataIn) then

  begin

    try

      if CryptProtectData(@DataIn, PChar('Hello Test'), nil,

        nil, nil, 0, @DataOut) then

      begin

        Writeln(GetDataBlobText(DataOut));

        Writeln(Format('%d bytes returned', [DataOut.cbData]));

        try

          if CryptUnprotectData(@DataOut, nil, nil, nil, nil, 0,

            @DataCheck) then

          begin

            try

              Writeln(GetDataBlobText(DataCheck));

            finally

              FreeDataBlob(DataCheck);

            end;

          end;

        finally

          FreeDataBlob(DataIn);

        end;

      end;

    finally

      FreeDataBlob(DataIn);

    end;

  end;

end;

procedure Test2;

begin

  Writeln(DecryptPassword('1111'));

end;

begin

  try

    Test1;

    Test2;

  except

    on E: Exception do

      Writeln(E.ClassName, ': ', E.Message);

  end;

end.

The.Ghost

The.Ghost

veyskarami