ما یه تایع API داریم به اسم RegisterHotKey که همانطور که از اسمش معلومه برای رجیستر کردن یه کلید میانبر هست که باید از این تابع استفاده کنی
به علاوه به تابع PeekMessage نیز احتیاج داری تا بررسی کنی اگر پیغام فرستاده شده یک HOTKEY-Message بود فلان کار رو بکنه
تو قسمت Unload فرمت هم باید از تابع UnregisterHotKey برای غیر فعال کردن میانبری که ایجاد کردی استفاده کنی.
مثال:
کد:
Private Const MOD_ALT = &H1
Private Const MOD_CONTROL = &H2
Private Const MOD_SHIFT = &H4
Private Const PM_REMOVE = &H1
Private Const WM_HOTKEY = &H312
Private Type POINTAPI
x As Long
y As Long
End Type
Private Type Msg
hWnd As Long
Message As Long
wParam As Long
lParam As Long
time As Long
pt As POINTAPI
End Type
Private Declare Function RegisterHotKey Lib "user32" (ByVal hWnd As Long, ByVal id As Long, ByVal fsModifiers As Long, ByVal vk As Long) As Long
Private Declare Function UnregisterHotKey Lib "user32" (ByVal hWnd As Long, ByVal id As Long) As Long
Private Declare Function PeekMessage Lib "user32" Alias "PeekMessageA" (lpMsg As Msg, ByVal hWnd As Long, ByVal wMsgFilterMin As Long, ByVal wMsgFilterMax As Long, ByVal wRemoveMsg As Long) As Long
Private Declare Function WaitMessage Lib "user32" () As Long
Private Unreg As Boolean
Private Sub WaitForMessage()
Dim Message As Msg
Do While Not Unreg
If PeekMessage(Message, Me.hWnd, WM_HOTKEY, WM_HOTKEY, PM_REMOVE) Then
WindowState = vbMinimized
End If
DoEvents
Loop
End Sub
Private Sub Form_Load()
Dim ret As Long
ret = RegisterHotKey(Me.hWnd, &HBFFF&, MOD_CONTROL, vbKeyF)
MsgBox "Press Ctrl+F for minimize window"
Show
WaitForMessage
End Sub
Private Sub Form_Unload(Cancel As Integer)
Unreg = True
Call UnregisterHotKey(Me.hWnd, &HBFFF&)
End Sub
پارامترهای تابع:
hWnd: هندلی که تابع تحت اون اجرا بشه
id: یه شناسه باید به میانبری که رجیستری میکنی بدی که یه مقدار از نوع Long هست، من اینجا بهش مقدار &HBFFF& رو دادم، شما بده 1000، این آی دی وقتی به کارت میاد که میخوای از تابع UnregisterHotKey استفاده کنی.
fsModifiers: کلیدی که باید با کلید مورد نظر شما فشار داده بشه، منظورم کلید های ALT و CTRL و SHIFT هست.
ثابت هایی که در این قسمت استفاده میشن عبارتند از:
MOD_ALT: یعنی باید ALT پایین نگه داشته شده باشه
MOD_CONTROL: یعنی باید CTRL پایین نگه داشته شده باشه
MOD_SHIFT: یعنی SHIFT باید پایین نگه داشته شده باشه
vk: کلید مورد نظر هست که میخوای رجیسترش کنی و میتونی برای اون از ثابت های خود وی بی استفاده کنی، مثلا برای کلید F باید بنویسی vbKeyF یا برای کلید A باید بنویسی vbKeyA
-----
حالا یه مثال دیگه در موردش میزنیم:
فرض کنیم من میخوام کلید ALT+N رو رجیستر کنم، برای اینکار تابع رو اینجوری فراخوانی میکنم:
کد:
RegisterHotKey(Me.hWnd, 9, MOD_ALT, vbKeyN)
در اینجا من آی دی این میانبر رو 9 تعیین کردم، پس برای غیرفعال کردن این میانبر از کد زیر استفاده میکنم:
کد:
UnregisterHotKey(Me.hWnd, 9)
فکر کنم کامل توضیح دادم
